home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / nt_dsp1.lzh / NT_DSP1.MSA / MATRIX / MATMUL3.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-01-24  |  2.8 KB  |  81 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; General Matrix Multiply-Accumulate, C=AB+Q
  7. ; 
  8. ; Last Update 04 Feb 87   Version 1.0
  9. ;
  10.         opt     cex
  11.         page    132,66,0,0
  12. ;
  13. ;       matrix multiply
  14. ;
  15. ;       Implements the matrix operation C=AB+Q
  16. ;
  17. ;       A 2x3
  18. mw      equ     2
  19. mx      equ     3
  20. ;       B 3x5
  21. my      equ     3
  22. mz      equ     5
  23. ;
  24. ;
  25. ;
  26.         org     x:0
  27. mat_a                           ; A matrix 2x3
  28.         dc        .4                    ;a(1,1)
  29.         dc        .3                    ;a(1,2)
  30.         dc        -.6                   ;a(1,3)
  31.         dc       .15                    ;a(2,1)
  32.         dc       -.8                    ;a(2,2)
  33.         dc       .25                    ;a(2,3)
  34.  
  35.         org     y:0
  36. mat_b                           ; B matrix 3x5
  37.         dc        -.4                   ;b(1,1)
  38.         dc        .35                   ;b(1,2)
  39.         dc       .15                    ;b(1,3)
  40.         dc        -.4                   ;b(1,4)
  41.         dc       .2                     ;b(1,5)
  42.         dc        .5                    ;b(2,1)
  43.         dc       -.3                    ;b(2,2)
  44.         dc       .4                     ;b(2,3)
  45.         dc        .1                    ;b(2,4)
  46.         dc       -.15                   ;b(2,5)
  47.         dc        .6                    ;b(3,1)
  48.         dc        -.35                  ;b(3,2)
  49.         dc       .45                    ;b(3,3)
  50.         dc        .25                   ;b(3,4)
  51.         dc        .2                    ;b(3,5)
  52.  
  53. mat_c   ds      mw*mz           ;output C martix 2x5
  54. mat_q   bsc     mw*mz,$200000   ;X array to add
  55. ;
  56. ;       matrix multiply for row major storage format
  57. ;
  58.         org     p:$100
  59. matmul  move    #mat_a,r0       ;point to A matrix
  60.         move    #mat_q,r2       ;matrix to add
  61.         move    #mat_b,r4       ;point to B matrix
  62.         move    #mat_c,r6       ;output to C matrix
  63.         move    #my,n0          ;second dimension of A
  64.         move    #mz,n5          ;second dimension of B
  65.  
  66.         do      #mw,_ew         ;number of final rows
  67.         do      #mz,_ez         ;number of final columns
  68.         move    r0,r1           ; copy ptr
  69.         move    r4,r5           ;copy second ptr
  70.         move    y:(r2)+,a       ;load element of X to add to
  71.         move    x:(r1)+,x0  y:(r5)+n5,y0        
  72.         rep     #my-1           ;inner sum
  73.         mac     x0,y0,a  x:(r1)+,x0  y:(r5)+n5,y0
  74.         macr    x0,y0,a   (r4)+ ;move to next column in B
  75.         move    a,y:(r6)+       ;save result
  76. _ez
  77.         move    (r0)+n0         ;move to next row in A
  78.         move    #mat_b,r4       ;point back to first column in B
  79. _ew
  80.         end
  81.